2009 UN BSS & IHY Workshop

Figure 1 Top: Bright type II solar radio spectrum (raw data) of Bleien, Switzerland. This dynamic spectrum was taken using a biconical antenna connected to an up-converter in front of Callisto. Beside a pulsating carrier at 30 MHz the spectrum is mostly quite clean from interference. Figure 1 Bottom: Single frequency spectrum at a specific time. The second plot is a relative plot by subtracting a quiet spectrum 20 seconds earlier.

Double plot in figure 1 was created using SSWIDL, see also here: http://www.astro.phys.ethz.ch/instrument/callisto/ecallisto/phoenix_howto.html Many procedures of SSWIDL allow easy plotting of light curves, single spectra and two-dimensional spectra. It is even possible to ‘add’, ‘subtract’ spectra. In addition, it is also possible to append spectra in time-range or frequency range. But this will be shown in a later essay. The appended SSWIDL program plots on a graphic window of the monitor and prints a jpg file in the local directory. For publication it is often necessary to supply encapsulated post script files. In this case all semicolons in line 13-14 and 36-37 have to be taken away.

Attachment IDL program:

PRO PlotCallistoSingleSpectrum
; check path/file carefully

loadct,5

path = 'C:\Dokumente und Einstellungen\Christian\Eigene Dateien\Projects\Essays\Spectrum\'
file = 'BLENSW_20090508_080012_59.fit.gz'

!p.multi = [0,1,2]; two plots in one column
!X.MARGIN=[10,3]
!Y.MARGIN=[5,3]

;set_plot,'PS'
;DEVICE, /ENCAPSULATED, BITS_PER_PIXEL=8, /COLOR, FILENAME =
path+'mySpectrum.eps',xsize=20.0,ysize=22.0

radio_spectro_fits_read, path + file, z, x, y

zz = constbacksub( z, /auto ) & xx = x & yy = y

elimwrongchannels, zz, xx, yy

spectro_plot, zz, xx,yy , xs=3, ys=3,$
xrange = '2009-May-08 08:' + ['08:00','09:40'], yrange = [80,20],$
ytitle='Frequency [MHz]',$
title = 'Callisto low frequency observation Bleien, Switzerland',$
xthick=2,ythick=2,ycharsize=1.2,xcharsize=1.2,charsize=1.2,charthick=2

p0 = 488*4; reference spectrum? : (08:08:20 - 08:00:12) * number of sweeps per second
p1 = 508*4; spectrum of interest: (08:08:40 - 08:00:12) * number of sweeps per second
dy = z[p1,*] - z[p0,*]; subtract background
plot,y,dy, xtickinterval=10, yrange=[0,40],$
xtitle = 'Frequency [MHz]', ytitle = 'Relative intensity [ADU]',$
title = 'Single spectrum of 2009-May-08 at 08:08:40 UT',$
xthick=2,ythick=2,ycharsize=1.2,xcharsize=1.2,charsize=1.2,charthick=2

;device,/close
;set_plot,'Win'

image3d = TVRD(TRUE=1)
WRITE_JPEG, path + 'MySpectrum.jpg', image3d, TRUE=1, QUALITY=100

end